hecmw_api_result_data.f90

Go to the documentation of this file.

!-------------------------------------------------------------------------------
! Copyright (c) 2026 FrontISTR Commons
! This software is released under the MIT License, see LICENSE.txt
!-------------------------------------------------------------------------------
 
module hecmw_api_result_data
  use iso_c_binding
  use hecmw_result, only : hecmwst_result_data
  implicit none
 
contains
 
  function hecmw_api_result_new() bind(C,name='hecmw_api_result_new')
    implicit none
    type(c_ptr) :: hecmw_api_result_new
    type(hecmwst_result_data), target, save :: hecresult
    hecmw_api_result_new = c_loc(hecresult)
  end function
 
  subroutine hecmw_api_result_delete(result) bind(C,name='hecmw_api_result_delete')
    implicit none
    type(c_ptr), value :: result
    type(hecmwst_result_data), pointer :: hecRESULT
    call c_f_pointer(cptr=result, fptr=hecresult)
    call hecmw_result_free(hecresult)
  end subroutine
 
  function hecmw_api_result_ng_component(result) bind(C,name='hecmw_api_result_ng_component')
    implicit none
    type(c_ptr), value :: result
    integer(c_int) :: hecmw_api_result_ng_component
    type(hecmwst_result_data), pointer :: hecresult
    call c_f_pointer(cptr=result, fptr=hecresult)
    hecmw_api_result_ng_component = hecresult%ng_component
  end function
 
  subroutine hecmw_api_result_global_val(result,i,dof,label,label_len,value) bind(C,name='hecmw_api_result_global_val')
    use hecmw_api_common, only : f_c_str_copy
    use hecmw_result
    implicit none
    type(c_ptr), value :: result
    integer(c_int), value :: i
    integer(c_int), intent(out) :: dof
    character(kind=c_char), intent(inout) :: label(*)
    integer(c_int), value, intent(in) :: label_len
    type(c_ptr), intent(out) :: value
 
    type(hecmwst_result_data), pointer :: hecRESULT
    integer :: index, j
 
    call c_f_pointer(cptr=result, fptr=hecresult)
    call f_c_str_copy(hecresult%global_label(i), label, label_len)
    index = 1
    do j=1, i-1
      index = index + hecresult%ng_dof(j)
    end do
    
    dof = hecresult%ng_dof(i)
    value = c_loc(hecresult%global_val_item(index))
  end subroutine
 
  function hecmw_api_result_nn_component(result) bind(C,name='hecmw_api_result_nn_component')
    implicit none
    type(c_ptr), value :: result
    integer(c_int) :: hecmw_api_result_nn_component
    type(hecmwst_result_data), pointer :: hecresult
    call c_f_pointer(cptr=result, fptr=hecresult)
    hecmw_api_result_nn_component = hecresult%nn_component
  end function
 
  subroutine hecmw_api_result_node_val(result,i,dim,index,dof,label,label_len,value) bind(C,name='hecmw_api_result_node_val')
    use hecmw_api_common, only : f_c_str_copy
    use hecmw_result
    implicit none
    type(c_ptr), value :: result
    integer(c_int), value :: i
    integer(c_int), intent(out) :: dim
    integer(c_int), intent(out) :: index
    integer(c_int), intent(out) :: dof
    character(kind=c_char), intent(inout) :: label(*)
    integer(c_int), value, intent(in) :: label_len
    type(c_ptr), intent(out) :: value
 
    type(hecmwst_result_data), pointer :: hecRESULT
    integer :: j
 
    call c_f_pointer(cptr=result, fptr=hecresult)
    call f_c_str_copy(hecresult%node_label(i), label, label_len)
 
    dof = hecresult%nn_dof(i)
    index = 0
    dim = 0
    do j=1, i-1
      index = index + hecresult%nn_dof(j)
      dim = dim + hecresult%nn_dof(j)
    end do
    do j=i, hecresult%nn_component
      dim = dim + hecresult%nn_dof(j)
    end do
    value = c_loc(hecresult%node_val_item)
  end subroutine
 
  function hecmw_api_result_ne_component(result) bind(C,name='hecmw_api_result_ne_component')
    implicit none
    type(c_ptr), value :: result
    integer(c_int) :: hecmw_api_result_ne_component
    type(hecmwst_result_data), pointer :: hecresult
    call c_f_pointer(cptr=result, fptr=hecresult)
    hecmw_api_result_ne_component = hecresult%ne_component
  end function
 
  subroutine hecmw_api_result_elem_val(result,i,dim,index,dof,label,label_len,value) bind(C,name='hecmw_api_result_elem_val')
    use hecmw_api_common, only : f_c_str_copy
    use hecmw_result
    implicit none
    type(c_ptr), value :: result
    integer(c_int), value :: i
    integer(c_int), intent(out) :: dim
    integer(c_int), intent(out) :: index
    integer(c_int), intent(out) :: dof
    character(kind=c_char), intent(inout) :: label(*)
    integer(c_int), value, intent(in) :: label_len
    type(c_ptr), intent(out) :: value
 
    integer :: j
    type(hecmwst_result_data), pointer :: hecRESULT
 
    call c_f_pointer(cptr=result, fptr=hecresult)
    call f_c_str_copy(hecresult%elem_label(i), label, label_len)
 
    dof = hecresult%ne_dof(i)
    index = 0
    dim = 0
    do j=1, i-1
      index = index + hecresult%ne_dof(j)
      dim = dim + hecresult%ne_dof(j)
    end do
    do j=i, hecresult%ne_component
      dim = dim + hecresult%ne_dof(j)
    end do
    value = c_loc(hecresult%elem_val_item)
  end subroutine
 
end module