hecmw_precond_SSOR_11.F90

Go to the documentation of this file.

!-------------------------------------------------------------------------------
! Copyright (c) 2019 FrontISTR Commons
! This software is released under the MIT License, see LICENSE.txt
!-------------------------------------------------------------------------------
 
!C
!C***
!C*** module hecmw_precond_SSOR_11
!C***
!C
module hecmw_precond_ssor_11
  use hecmw_util
  use hecmw_matrix_misc
  use m_hecmw_matrix_ordering_cm
  use m_hecmw_matrix_ordering_mc
  use hecmw_matrix_reorder
#ifndef _OPENACC
  !$ use omp_lib
#endif
 
  private
 
  public:: hecmw_precond_ssor_11_setup
  public:: hecmw_precond_ssor_11_apply
  public:: hecmw_precond_ssor_11_clear
 
  integer(kind=kint) :: N
  real(kind=kreal), pointer :: d(:) => null()
  real(kind=kreal), pointer :: al(:) => null()
  real(kind=kreal), pointer :: au(:) => null()
  integer(kind=kint), pointer :: indexL(:) => null()
  integer(kind=kint), pointer :: indexU(:) => null()
  integer(kind=kint), pointer :: itemL(:) => null()
  integer(kind=kint), pointer :: itemU(:) => null()
  real(kind=kreal), pointer :: alu(:) => null()
 
  integer(kind=kint) :: NColor
  integer(kind=kint), pointer :: COLORindex(:) => null()
  integer(kind=kint), pointer :: perm(:) => null()
  integer(kind=kint), pointer :: iperm(:) => null()
 
  logical, save :: isFirst = .true.
 
  logical, save :: INITIALIZED = .false.
 
  ! relaxation parameter of
  !   M = 1/(2-OMEGA) (D/OMEGA + L) (D/OMEGA)^-1 (D/OMEGA + U)
  ! OMEGA = 1 is the classic (D+L) D^-1 (D+U).  _apply is handed only ZP, so setup
  ! leaves the value here for it.
  real(kind=kreal), save :: omega = 1.d0
 
  ! for tuning
  integer(kind=kint), parameter :: numOfBlockPerThread = 100
  integer(kind=kint), save :: numOfThread = 1, numofblock
  integer(kind=kint), save, allocatable :: icToBlockIndex(:)
  integer(kind=kint), save, allocatable :: blockIndexToColorIndex(:)
  integer(kind=kint), save :: sectorCacheSize0, sectorCacheSize1
 
  integer(kind=kint), parameter :: SSOR_DEBUG = 0
 
contains
 
  subroutine hecmw_precond_ssor_11_setup(hecMAT)
    implicit none
    type(hecmwst_matrix), intent(inout) :: hecmat
    integer(kind=kint ) :: npl, npu
    integer(kind=kint ) :: ncolor_in
    real   (kind=kreal) :: omega_inv
    real   (kind=kreal) :: alutmp(1,1), pw(1)
    integer(kind=kint ) :: ii, i, j, k
    integer(kind=kint ) :: nthreads = 1
    integer(kind=kint ), allocatable :: perm_tmp(:)
    real   (kind=kreal) :: t0
 
    if (ssor_debug >= 1) then
      t0 = hecmw_wtime()
      write(*,*) 'DEBUG: SSOR setup start', hecmw_wtime()-t0
    endif
 
    if (initialized) then
      if (hecmat%Iarray(98) == 1) then ! need symbolic and numerical setup
        call hecmw_precond_ssor_11_clear(hecmat)
      else if (hecmat%Iarray(97) == 1) then ! need numerical setup only
        call hecmw_precond_ssor_11_clear(hecmat) ! TEMPORARY
      else
        return
      endif
    endif
 
#ifndef _OPENACC
    !$ nthreads = omp_get_max_threads()
#endif
 
    n = hecmat%N
    ! N = hecMAT%NP
    ncolor_in = hecmw_mat_get_ncolor_in(hecmat)
    omega = hecmw_mat_get_omega(hecmat)
    omega_inv = 1.d0 / omega
 
#ifdef _OPENACC
    allocate(colorindex(0:n), perm_tmp(n), perm(n), iperm(n))
    call hecmw_matrix_ordering_rcm(n, hecmat%indexL, hecmat%itemL, &
      hecmat%indexU, hecmat%itemU, perm_tmp, iperm)
    if (ssor_debug >= 1) write(*,*) 'DEBUG: RCM ordering done', hecmw_wtime()-t0
    call hecmw_matrix_ordering_mc(n, hecmat%indexL, hecmat%itemL, &
      hecmat%indexU, hecmat%itemU, perm_tmp, &
      ncolor_in, ncolor, colorindex, perm, iperm)
    if (ssor_debug >= 1) write(*,*) 'DEBUG: MC ordering done', hecmw_wtime()-t0
    deallocate(perm_tmp)
 
#else
    if (nthreads == 1) then
      ncolor = 1
      allocate(colorindex(0:1), perm(n), iperm(n))
      colorindex(0) = 0
      colorindex(1) = n
      do i=1,n
        perm(i) = i
        iperm(i) = i
      end do
    else
      allocate(colorindex(0:n), perm_tmp(n), perm(n), iperm(n))
      call hecmw_matrix_ordering_rcm(n, hecmat%indexL, hecmat%itemL, &
        hecmat%indexU, hecmat%itemU, perm_tmp, iperm)
      if (ssor_debug >= 1) write(*,*) 'DEBUG: RCM ordering done', hecmw_wtime()-t0
      call hecmw_matrix_ordering_mc(n, hecmat%indexL, hecmat%itemL, &
        hecmat%indexU, hecmat%itemU, perm_tmp, &
        ncolor_in, ncolor, colorindex, perm, iperm)
      if (ssor_debug >= 1) write(*,*) 'DEBUG: MC ordering done', hecmw_wtime()-t0
      deallocate(perm_tmp)
 
    endif
#endif
 
    npl = 0
    do i=1,n
      do j=hecmat%indexU(i-1)+1,hecmat%indexU(i)
        if( hecmat%itemU(j) > n ) exit
        npl = npl + 1
      enddo
    enddo
    npl = max(hecmat%indexL(n),npl)
    npu = hecmat%indexU(n)
    allocate(indexl(0:n), indexu(0:n), iteml(npl), itemu(npu))
    call hecmw_matrix_reorder_profile(n, perm, iperm, &
      hecmat%indexL, hecmat%indexU, hecmat%itemL, hecmat%itemU, &
      indexl, indexu, iteml, itemu)
    if (ssor_debug >= 1) write(*,*) 'DEBUG: reordering profile done', hecmw_wtime()-t0
 
 
    allocate(d(n), al(npl), au(npu))
    call hecmw_matrix_reorder_values(n, 1, perm, iperm, &
      hecmat%indexL, hecmat%indexU, hecmat%itemL, hecmat%itemU, &
      hecmat%AL, hecmat%AU, hecmat%D, &
      indexl, indexu, iteml, itemu, al, au, d)
    if (ssor_debug >= 1) write(*,*) 'DEBUG: reordering values done', hecmw_wtime()-t0
 
    call hecmw_matrix_reorder_renum_item(n, perm, indexl, iteml)
    call hecmw_matrix_reorder_renum_item(n, perm, indexu, itemu)
 
    allocate(alu(n))
    alu  = 0.d0
 
    do ii= 1, n
      alu(ii) = d(ii)
    enddo
 
#ifdef _OPENACC
    !$acc kernels
    !$acc loop independent private(ALUtmp)
#else
    !$omp parallel default(none),private(ii,ALUtmp,k,i,j,PW),shared(N,ALU,OMEGA_INV)
    !$omp do
#endif
    do ii= 1, n
      alutmp(1,1)= alu(ii) * omega_inv
      alutmp(1,1)= 1.d0/alutmp(1,1)
      alu(ii)= alutmp(1,1)
    enddo
#ifdef _OPENACC
    !$acc end kernels
#else
    !$omp end do
    !$omp end parallel
#endif
 
    isfirst = .true.
 
    initialized = .true.
    hecmat%Iarray(98) = 0 ! symbolic setup done
    hecmat%Iarray(97) = 0 ! numerical setup done
 
    if (ssor_debug >= 1) write(*,*) 'DEBUG: SSOR setup done', hecmw_wtime()-t0
 
  end subroutine hecmw_precond_ssor_11_setup
 
  subroutine setup_tuning_parameters
    use hecmw_tuning_fx
    implicit none
    integer(kind=kint) :: blockindex, elementcount, numofelement, ii
    real(kind=kreal) :: numofelementperblock
    integer(kind=kint) :: ic, i
    if (ssor_debug >= 1) write(*,*) 'DEBUG: setting up tuning parameters for SSOR'
#ifndef _OPENACC
    !$ numOfThread = omp_get_max_threads()
#endif
 
    numofblock = numofthread * numofblockperthread
    if (allocated(ictoblockindex)) deallocate(ictoblockindex)
    if (allocated(blockindextocolorindex)) deallocate(blockindextocolorindex)
    allocate (ictoblockindex(0:ncolor), &
         blockindextocolorindex(0:numofblock + ncolor))
    numofelement = n + indexl(n) + indexu(n)
    numofelementperblock = dble(numofelement) / numofblock
    blockindex = 0
    ictoblockindex = -1
    ictoblockindex(0) = 0
    blockindextocolorindex = -1
    blockindextocolorindex(0) = 0
    do ic = 1, ncolor
      elementcount = 0
      ii = 1
      do i = colorindex(ic-1)+1, colorindex(ic)
        elementcount = elementcount + 1
        elementcount = elementcount + (indexl(i) - indexl(i-1))
        elementcount = elementcount + (indexu(i) - indexu(i-1))
        if (elementcount > ii * numofelementperblock &
             .or. i == colorindex(ic)) then
          ii = ii + 1
          blockindex = blockindex + 1
          blockindextocolorindex(blockindex) = i
        endif
      enddo
      ictoblockindex(ic) = blockindex
    enddo
    numofblock = blockindex
 
    call hecmw_tuning_fx_calc_sector_cache( n, 1, &
         sectorcachesize0, sectorcachesize1 )
  end subroutine setup_tuning_parameters
 
  subroutine hecmw_precond_ssor_11_apply(ZP)
    implicit none
    real(kind=kreal), intent(inout) :: zp(:)
    integer(kind=kint) :: ic, i, iold, j, isl, iel, isu, ieu, k
    real(kind=kreal) :: sw1, x1
 
    real(kind=kreal) :: omega_fac
 
    ! added for tuning >>>
    integer(kind=kint) :: blockindex
 
#ifndef _OPENACC
    if (isfirst) then
      call setup_tuning_parameters
      isfirst = .false.
    endif
#endif
    ! <<< added for tuning
 
    omega_fac = 2.d0 - omega
 
#ifndef _OPENACC
    !call start_collection("loopInPrecond11")
 
    !OCL CACHE_SECTOR_SIZE(sectorCacheSize0,sectorCacheSize1)
    !OCL CACHE_SUBSECTOR_ASSIGN(ZP)
 
    !$omp parallel default(none) &
      !$omp&shared(NColor,indexL,itemL,indexU,itemU,AL,AU,D,ALU,perm,&
      !$omp&       ZP,icToBlockIndex,blockIndexToColorIndex,OMEGA_FAC) &
      !$omp&private(SW1,X1,ic,i,iold,isL,ieL,isU,ieU,j,k,blockIndex)
#endif
 
    !C-- FORWARD
    do ic=1,ncolor
#ifdef _OPENACC
      !$acc kernels
      !$acc loop independent
      do i = colorindex(ic-1)+1, colorindex(ic)
#else
      !$omp do schedule (static, 1)
      do blockindex = ictoblockindex(ic-1)+1, ictoblockindex(ic)
        do i = blockindextocolorindex(blockindex-1)+1, &
            blockindextocolorindex(blockindex)
#endif
          iold = perm(i)
          sw1= omega_fac * zp(iold)
          isl= indexl(i-1)+1
          iel= indexl(i)
          do j= isl, iel
            k= iteml(j)
            x1= zp(k)
            sw1= sw1 - al(j)*x1
          enddo ! j
 
          x1= alu(i  )*  sw1
          zp(iold)= x1
#ifdef _OPENACC
      enddo
      !$acc end kernels
#else
        enddo ! i
      enddo ! blockIndex
      !$omp end do
#endif
    enddo ! ic
 
    !C-- BACKWARD
    do ic=ncolor, 1, -1
#ifdef _OPENACC
      !$acc kernels
      !$acc loop independent
      do i = colorindex(ic-1)+1, colorindex(ic)
#else
      !$omp do schedule (static, 1)
      do blockindex = ictoblockindex(ic), ictoblockindex(ic-1)+1, -1
        do i = blockindextocolorindex(blockindex), &
            blockindextocolorindex(blockindex-1)+1, -1
#endif
          ! do blockIndex = icToBlockIndex(ic-1)+1, icToBlockIndex(ic)
          !   do i = blockIndexToColorIndex(blockIndex-1)+1, &
            !        blockIndexToColorIndex(blockIndex)
          !   do i = endPos(threadNum, ic), startPos(threadNum, ic), -1
          sw1= 0.d0
          isu= indexu(i-1) + 1
          ieu= indexu(i)
          do j= ieu, isu, -1
            k= itemu(j)
            x1= zp(k)
            sw1= sw1 + au(j)*x1
          enddo ! j
 
          x1= alu(i)*  sw1
 
          iold = perm(i)
          zp(iold)=  zp(iold) - x1
#ifdef _OPENACC
      enddo
      !$acc end kernels
#else
        enddo ! i
      enddo ! blockIndex
      !$omp end do
#endif
    enddo ! ic
#ifndef _OPENACC
    !$omp end parallel
 
    !OCL END_CACHE_SUBSECTOR
    !OCL END_CACHE_SECTOR_SIZE
 
    !call stop_collection("loopInPrecond11")
#endif
 
  end subroutine hecmw_precond_ssor_11_apply
 
  subroutine hecmw_precond_ssor_11_clear(hecMAT)
    implicit none
    type(hecmwst_matrix), intent(inout) :: hecmat
    if (associated(colorindex)) deallocate(colorindex)
    if (associated(perm)) deallocate(perm)
    if (associated(iperm)) deallocate(iperm)
    if (associated(alu)) deallocate(alu)
    if (associated(d)) deallocate(d)
    if (associated(al)) deallocate(al)
    if (associated(au)) deallocate(au)
    if (associated(indexl)) deallocate(indexl)
    if (associated(indexu)) deallocate(indexu)
    if (associated(iteml)) deallocate(iteml)
    if (associated(itemu)) deallocate(itemu)
    nullify(colorindex)
    nullify(perm)
    nullify(iperm)
    nullify(alu)
    nullify(d)
    nullify(al)
    nullify(au)
    nullify(indexl)
    nullify(indexu)
    nullify(iteml)
    nullify(itemu)
    initialized = .false.
  end subroutine hecmw_precond_ssor_11_clear
 
end module     hecmw_precond_ssor_11