m_timepoint.f90

Go to the documentation of this file.

!-------------------------------------------------------------------------------
! Copyright (c) 2019 FrontISTR Commons
! This software is released under the MIT License, see LICENSE.txt
!-------------------------------------------------------------------------------
module m_timepoint
  use hecmw
  implicit none
 
  integer, parameter :: tprstep  = 1
  integer, parameter :: tprtotal = 2
 
  type time_points
    character( len=80 )        :: name
    integer                    :: n_points
    integer                    :: range_type
    real(kind=kreal), pointer  :: points(:) => null()  
  end type
 
contains
 
  logical function is_at_timepoints(totaltime,starttime,tp)
    real(kind=kreal), intent(in)  :: totaltime  
    real(kind=kreal), intent(in)  :: starttime  
    type(time_points), intent(in) :: tp
 
    integer           :: i
    real(kind=kreal)  :: time
 
    time = totaltime
    if( tp%range_type == tprstep ) time = totaltime - starttime
 
    is_at_timepoints =.false.
    do i=1,tp%n_points
      if( dabs(time-tp%points(i)) > 1.d-10 ) cycle
      is_at_timepoints = .true.
      exit
    end do
 
  end function
 
  real(kind=kreal) function get_remain_to_next_timepoints(totaltime,starttime,tp)
    real(kind=kreal), intent(in)  :: totaltime  
    real(kind=kreal), intent(in)  :: starttime  
    type(time_points), intent(in) :: tp
 
    integer           :: i
    real(kind=kreal)  :: time
 
    time = totaltime
    if( tp%range_type == tprstep ) time = totaltime - starttime
 
    get_remain_to_next_timepoints = 1.d+10
    if( time < tp%points(1)-1.d-10 ) then
      get_remain_to_next_timepoints = tp%points(1)-time
    end if
    do i=1,tp%n_points-1
      if( time < tp%points(i)-1.d-10 ) cycle
      if( time >= tp%points(i+1)-1.d-10 ) cycle
      get_remain_to_next_timepoints = tp%points(i+1)-time
      exit
    end do
 
  end function
 
end module