hecmw_solver_direct_MKL.f90

Go to the documentation of this file.

!-------------------------------------------------------------------------------
! Copyright (c) 2019 FrontISTR Commons
! This software is released under the MIT License, see LICENSE.txt
!-------------------------------------------------------------------------------
 
module hecmw_solver_direct_mkl
  use hecmw_util
  use m_sparse_matrix
  use m_sparse_matrix_hec
  use m_hecmw_mkl_wrapper
  use hecmw_matrix_ass
  use hecmw_matrix_dump
 
  private
  public :: hecmw_solve_direct_mkl
 
  logical, save :: INITIALIZED = .false.
  type (sparse_matrix), save :: spMAT
 
contains
 
  subroutine hecmw_solve_direct_mkl(hecMESH,hecMAT)
    implicit none
    type (hecmwst_local_mesh), intent(in) :: hecmesh
    type (hecmwst_matrix    ), intent(inout) :: hecmat
    integer(kind=kint) :: spmat_type
    integer(kind=kint) :: spmat_symtype
    integer(kind=kint) :: phase_start
    integer(kind=kint) :: istat,myrank
    real(kind=kreal) :: t1,t2
 
    t1=hecmw_wtime()
 
    call hecmw_mat_dump(hecmat, hecmesh)
 
    myrank=hecmw_comm_get_rank()
 
    if (initialized .and. hecmat%Iarray(98) .eq. 1) then
      call sparse_matrix_finalize(spmat)
      initialized = .false.
    endif
 
    if (.not. initialized) then
      spmat_type = sparse_matrix_type_csr
      if (hecmat%symmetric) then
        spmat_symtype = sparse_matrix_symtype_sym
      else
        spmat_symtype = sparse_matrix_symtype_asym
      end if
      call sparse_matrix_set_type(spmat, spmat_type, spmat_symtype)
 
      initialized = .true.
      hecmat%Iarray(98) = 1
    endif
 
    !* Flag to activate symbolic factorization: 1(yes) 0(no)  hecMESH%Iarray(98)
    !* Flag to activate numeric  factorization: 1(yes) 0(no)  hecMESH%Iarray(97)
 
    if (hecmat%Iarray(98) .eq. 1) then
      ! ANALYSIS and FACTORIZATION
      call sparse_matrix_hec_init_prof(spmat, hecmat, hecmesh)
      call sparse_matrix_hec_set_vals(spmat, hecmat)
      !call sparse_matrix_dump(spMAT)
      phase_start = 1
      hecmat%Iarray(98) = 0
      hecmat%Iarray(97) = 0
    endif
    if (hecmat%Iarray(97) .eq. 1) then
      ! FACTORIZATION
      call sparse_matrix_hec_set_vals(spmat, hecmat)
      !call sparse_matrix_dump(spMAT)
      phase_start = 2
      hecmat%Iarray(97) = 0
    endif
    call sparse_matrix_hec_set_rhs(spmat, hecmat)
 
    t2=hecmw_wtime()
    if (myrank==0 .and. (spmat%iterlog > 0 .or. spmat%timelog > 0)) &
       write(*,'(A,f10.3)') ' [Pardiso]: Setup completed.          time(sec)=',t2-t1
 
    ! SOLVE
    call hecmw_mkl_wrapper(spmat, phase_start, hecmat%X, istat)
 
    call hecmw_mat_dump_solution(hecmat)
 
  end subroutine hecmw_solve_direct_mkl
 
end module hecmw_solver_direct_mkl