fstr_Spring.f90

Go to the documentation of this file.

!-------------------------------------------------------------------------------
! Copyright (c) 2019 FrontISTR Commons
! This software is released under the MIT License, see LICENSE.txt
!-------------------------------------------------------------------------------
 
module m_fstr_spring
  implicit none
contains
 
  subroutine fstr_addspring(cstep, hecMESH, hecMAT, fstrSOLID, fstrPARAM)
    use m_fstr
    use m_static_lib
    integer, intent(in)                  :: cstep
    type (hecmwST_matrix),intent(inout)  :: hecMAT
    type (hecmwST_local_mesh),intent(in) :: hecMESH
    type (fstr_solid),intent(inout)      :: fstrSOLID
    type (fstr_param),intent(inout)      :: fstrPARAM
 
    integer(kind=kint) :: grpid, ndof, ig0, ig, ityp, iS0, iE0, ik, in, idx, num
    real(kind=kreal) :: fval, factor
 
    factor = fstrsolid%factor(2)
 
    ndof = hecmat%NDOF
    do ig0= 1, fstrsolid%SPRING_ngrp_tot
      grpid = fstrsolid%SPRING_ngrp_GRPID(ig0)
      if( .not. fstr_isloadactive( fstrsolid, grpid, cstep ) ) cycle
      ig= fstrsolid%SPRING_ngrp_ID(ig0)
      ityp= fstrsolid%SPRING_ngrp_DOF(ig0)
      fval= fstrsolid%SPRING_ngrp_val(ig0)
      if( fval < 0.d0 ) fval = -fval*(1.d0-factor)
 
      is0= hecmesh%node_group%grp_index(ig-1) + 1
      ie0= hecmesh%node_group%grp_index(ig  )
      do ik= is0, ie0
        in = hecmesh%node_group%grp_item(ik)
        idx = ndof**2 * (in - 1) + ndof * (ityp - 1) + ityp
        hecmat%D(idx) = hecmat%D(idx) + fval
      enddo
    enddo
 
  end subroutine fstr_addspring
 
  subroutine fstr_update_ndforce_spring( cstep, hecMESH, fstrSOLID, B )
    use m_fstr
    integer(kind=kint), intent(in)       :: cstep
    type (hecmwST_local_mesh),intent(in) :: hecMESH
    type (fstr_solid), intent(in)        :: fstrSOLID
    real(kind=kreal), intent(inout)      :: b(:)       
    !    Local variables
    integer(kind=kint) ndof,ig0,ig,ityp,iS0,iE0,ik,in,idx,num
    integer(kind=kint) :: grpid
    real(kind=kreal) :: fval, factor
 
    factor = fstrsolid%factor(2)
 
    ndof = hecmesh%n_dof
    do ig0= 1, fstrsolid%SPRING_ngrp_tot
      grpid = fstrsolid%SPRING_ngrp_GRPID(ig0)
      if( .not. fstr_isloadactive( fstrsolid, grpid, cstep ) ) cycle
      ig= fstrsolid%SPRING_ngrp_ID(ig0)
      ityp= fstrsolid%SPRING_ngrp_DOF(ig0)
      fval= fstrsolid%SPRING_ngrp_val(ig0)
      if( fval < 0.d0 ) fval = -fval*(1.d0-factor)
 
      is0= hecmesh%node_group%grp_index(ig-1) + 1
      ie0= hecmesh%node_group%grp_index(ig  )
      do ik= is0, ie0
        in = hecmesh%node_group%grp_item(ik)
        idx = ndof * (in - 1) + ityp
        b(idx) = b(idx) - fval * ( fstrsolid%dunode( idx ) + fstrsolid%unode( idx ) )
      enddo
    enddo
  end subroutine fstr_update_ndforce_spring
 
end module m_fstr_spring