hecmw_mf_graph.f90

Go to the documentation of this file.

!-------------------------------------------------------------------------------
! Copyright (c) 2026 FrontISTR Commons
! This software is released under the MIT License, see LICENSE.txt
!-------------------------------------------------------------------------------
module hecmw_mf_graph
  use hecmw_util
  implicit none
 
  private
  public :: hecmwst_mf_graph
  public :: hecmw_mf_graph_from_hecmat
  public :: hecmw_mf_graph_set
  public :: hecmw_mf_graph_finalize
 
  type hecmwst_mf_graph
    integer(kind=kint) :: nnode = 0
    integer(kind=kint), allocatable :: ndof(:)
    integer(kind=kint), allocatable :: dofptr(:)
    integer(kind=kint), allocatable :: xadj(:)
    integer(kind=kint), allocatable :: adjncy(:)
  end type hecmwst_mf_graph
 
contains
 
  subroutine hecmw_mf_graph_from_hecmat(hecMAT, graph)
    implicit none
    type(hecmwst_matrix), intent(in) :: hecmat
    type(hecmwst_mf_graph), intent(out) :: graph
    integer(kind=kint) :: n, i, k, l
 
    n = hecmat%NP
    graph%nnode = n
    allocate(graph%ndof(n))
    allocate(graph%dofptr(n+1))
    allocate(graph%xadj(n+1))
    graph%ndof(1:n) = hecmat%NDOF
    graph%dofptr(1) = 1
    graph%xadj(1) = 1
    do i = 1, n
      graph%dofptr(i+1) = graph%dofptr(i) + graph%ndof(i)
      graph%xadj(i+1) = graph%xadj(i) &
        + (hecmat%indexL(i) - hecmat%indexL(i-1)) + (hecmat%indexU(i) - hecmat%indexU(i-1))
    enddo
    allocate(graph%adjncy(graph%xadj(n+1)-1))
    l = 0
    do i = 1, n
      do k = hecmat%indexL(i-1)+1, hecmat%indexL(i)
        l = l + 1
        graph%adjncy(l) = hecmat%itemL(k)
      enddo
      do k = hecmat%indexU(i-1)+1, hecmat%indexU(i)
        l = l + 1
        graph%adjncy(l) = hecmat%itemU(k)
      enddo
    enddo
  end subroutine hecmw_mf_graph_from_hecmat
 
  subroutine hecmw_mf_graph_set(graph, nnode, ndof, xadj, adjncy)
    implicit none
    type(hecmwst_mf_graph), intent(out) :: graph
    integer(kind=kint), intent(in) :: nnode
    integer(kind=kint), intent(in) :: ndof(:)
    integer(kind=kint), intent(in) :: xadj(:)
    integer(kind=kint), intent(in) :: adjncy(:)
    integer(kind=kint) :: i
 
    graph%nnode = nnode
    allocate(graph%ndof(nnode))
    allocate(graph%dofptr(nnode+1))
    allocate(graph%xadj(nnode+1))
    allocate(graph%adjncy(xadj(nnode+1)-1))
    graph%ndof(1:nnode) = ndof(1:nnode)
    graph%dofptr(1) = 1
    do i = 1, nnode
      graph%dofptr(i+1) = graph%dofptr(i) + graph%ndof(i)
    enddo
    graph%xadj(1:nnode+1) = xadj(1:nnode+1)
    graph%adjncy(1:xadj(nnode+1)-1) = adjncy(1:xadj(nnode+1)-1)
  end subroutine hecmw_mf_graph_set
 
  subroutine hecmw_mf_graph_finalize(graph)
    implicit none
    type(hecmwst_mf_graph), intent(inout) :: graph
 
    graph%nnode = 0
    if (allocated(graph%ndof)) deallocate(graph%ndof)
    if (allocated(graph%dofptr)) deallocate(graph%dofptr)
    if (allocated(graph%xadj)) deallocate(graph%xadj)
    if (allocated(graph%adjncy)) deallocate(graph%adjncy)
  end subroutine hecmw_mf_graph_finalize
 
end module hecmw_mf_graph