hecmw_Jacob_231.f90

Go to the documentation of this file.

!-------------------------------------------------------------------------------
! Copyright (c) 2019 FrontISTR Commons
! This software is released under the MIT License, see LICENSE.txt
!-------------------------------------------------------------------------------
 
module hecmw_jacob231
contains
 
  subroutine hecmw_jacob_231 ( hecMESH, iElem, DET, W, N, NX, NY )
    use hecmw_util
    implicit none
 
    type(hecmwst_local_mesh):: hecMESH
    integer(kind=kint)::       iElem
    real(kind=kreal)::         det
    real(kind=kreal)::         w(3),n(3,3),nx(3,3),ny(3,3)
 
    integer(kind=kint):: i, ii, j, iLocal
    real(kind=kreal):: dum
    real(kind=kreal):: xx(3), yy(3)
    real(kind=kreal):: nr(3), ns(3)
    real(kind=kreal):: jacob(2,2), jinv(2,2)
 
    !!
    !! ******** Set values of coordinates********
    !!
    do i = 1, 3
      ii = 3 - i
      ilocal = hecmesh%elem_node_item( 3*ielem -ii )
      xx(i) = hecmesh%node( ilocal*3 -1 )
      yy(i) = hecmesh%node( ilocal*3    )
      w(i)  = 1.0 / 3.0d0
    end do
 
    !!
    !! ******** Set values to shape functions ********
    !!
    n(1,1) = 0.5d0
    n(2,1) = 0.5d0
    n(3,1) = 0.0d0
 
    n(1,2) = 0.0d0
    n(2,2) = 0.5d0
    n(3,2) = 0.5d0
 
    n(1,3) = 0.5d0
    n(2,3) = 0.0d0
    n(3,3) = 0.5d0
    !!
    !! ******** Derivative of shape functions ********
    !!
    !! ----------- For R-Coordinate -------------
    nr(1) = 1.0d0
    nr(2) = 0.0d0
    nr(3) =-1.0d0
    !! ----------- For S-Coordinate -------------
    ns(1) = 0.0d0
    ns(2) = 1.0d0
    ns(3) =-1.0d0
    !!
    !! ******** Jacobi matrix calculation********
    !!
    jacob(1,1) = nr(1)*xx(1)+nr(2)*xx(2)+nr(3)*xx(3)
    jacob(2,1) = ns(1)*xx(1)+ns(2)*xx(2)+ns(3)*xx(3)
    jacob(1,2) = nr(1)*yy(1)+nr(2)*yy(2)+nr(3)*yy(3)
    jacob(2,2) = ns(1)*yy(1)+ns(2)*yy(2)+ns(3)*yy(3)
 
    det = jacob(1,1)*jacob(2,2) - jacob(1,2)*jacob(2,1)
    !!
    !! ******** Inverse Jacobi matrix calculation ********
    !!
    dum = 1.0 / det
    jinv(1,1) =  dum * jacob(2,2)
    jinv(2,1) = -dum * jacob(1,2)
    jinv(1,2) = -dum * jacob(2,1)
    jinv(2,2) =  dum * jacob(1,1)
 
    do i = 1, 3
      do j = 1, 3
 
        nx(i,j) = jinv(1,1)*nr(i) + jinv(1,2)*ns(i)
        ny(i,j) = jinv(2,1)*nr(i) + jinv(2,2)*ns(i)
 
      end do
    end do
 
  end subroutine hecmw_jacob_231
end module hecmw_jacob231