hecmw_precond_SSOR_22.F90

Go to the documentation of this file.

!-------------------------------------------------------------------------------
! Copyright (c) 2019 FrontISTR Commons
! This software is released under the MIT License, see LICENSE.txt
!-------------------------------------------------------------------------------
 
!C
!C***
!C*** module hecmw_precond_SSOR_22
!C***
!C
module hecmw_precond_ssor_22
  use hecmw_util
  use hecmw_matrix_misc
  use m_hecmw_matrix_ordering_cm
  use m_hecmw_matrix_ordering_mc
  use hecmw_matrix_reorder
#ifndef _OPENACC
  !$ use omp_lib
#endif
 
  private
 
  public:: hecmw_precond_ssor_22_setup
  public:: hecmw_precond_ssor_22_apply
  public:: hecmw_precond_ssor_22_clear
 
  integer(kind=kint) :: N
  real(kind=kreal), pointer :: d(:) => null()
  real(kind=kreal), pointer :: al(:) => null()
  real(kind=kreal), pointer :: au(:) => null()
  integer(kind=kint), pointer :: indexL(:) => null()
  integer(kind=kint), pointer :: indexU(:) => null()
  integer(kind=kint), pointer :: itemL(:) => null()
  integer(kind=kint), pointer :: itemU(:) => null()
  real(kind=kreal), pointer :: alu(:) => null()
 
  integer(kind=kint) :: NColor
  integer(kind=kint), pointer :: COLORindex(:) => null()
  integer(kind=kint), pointer :: perm(:) => null()
  integer(kind=kint), pointer :: iperm(:) => null()
 
  logical, save :: isFirst = .true.
 
  logical, save :: INITIALIZED = .false.
 
contains
 
  subroutine hecmw_precond_ssor_22_setup(hecMAT)
    implicit none
    type(hecmwst_matrix), intent(inout) :: hecmat
    integer(kind=kint ) :: npl, npu
    integer(kind=kint ) :: ncolor_in
    real   (kind=kreal) :: sigma_diag
    real   (kind=kreal) :: alutmp(2,2), pw(2)
    integer(kind=kint ) :: ii, i, j, k
    integer(kind=kint ) :: nthreads = 1
    integer(kind=kint ), allocatable :: perm_tmp(:)
    !real   (kind=kreal) :: t0
 
    !t0 = hecmw_Wtime()
    !write(*,*) 'DEBUG: SSOR setup start', hecmw_Wtime()-t0
 
    if (initialized) then
      if (hecmat%Iarray(98) == 1) then ! need symbolic and numerical setup
        call hecmw_precond_ssor_22_clear(hecmat)
      else if (hecmat%Iarray(97) == 1) then ! need numerical setup only
        call hecmw_precond_ssor_22_clear(hecmat) ! TEMPORARY
      else
        return
      endif
    endif
 
#ifndef _OPENACC
    !$ nthreads = omp_get_max_threads()
#endif
 
    n = hecmat%N
    ! N = hecMAT%NP
    ncolor_in = hecmw_mat_get_ncolor_in(hecmat)
    sigma_diag = hecmw_mat_get_sigma_diag(hecmat)
 
#ifdef _OPENACC
    allocate(colorindex(0:n), perm_tmp(n), perm(n), iperm(n))
    call hecmw_matrix_ordering_rcm(n, hecmat%indexL, hecmat%itemL, &
      hecmat%indexU, hecmat%itemU, perm_tmp, iperm)
    !write(*,*) 'DEBUG: RCM ordering done', hecmw_Wtime()-t0
    call hecmw_matrix_ordering_mc(n, hecmat%indexL, hecmat%itemL, &
      hecmat%indexU, hecmat%itemU, perm_tmp, &
      ncolor_in, ncolor, colorindex, perm, iperm)
    !write(*,*) 'DEBUG: MC ordering done', hecmw_Wtime()-t0
    deallocate(perm_tmp)
 
#else
    if (nthreads == 1) then
      ncolor = 1
      allocate(colorindex(0:1), perm(n), iperm(n))
      colorindex(0) = 0
      colorindex(1) = n
      do i=1,n
        perm(i) = i
        iperm(i) = i
      end do
    else
      allocate(colorindex(0:n), perm_tmp(n), perm(n), iperm(n))
      call hecmw_matrix_ordering_rcm(n, hecmat%indexL, hecmat%itemL, &
        hecmat%indexU, hecmat%itemU, perm_tmp, iperm)
      !write(*,*) 'DEBUG: RCM ordering done', hecmw_Wtime()-t0
      call hecmw_matrix_ordering_mc(n, hecmat%indexL, hecmat%itemL, &
        hecmat%indexU, hecmat%itemU, perm_tmp, &
        ncolor_in, ncolor, colorindex, perm, iperm)
      !write(*,*) 'DEBUG: MC ordering done', hecmw_Wtime()-t0
      deallocate(perm_tmp)
 
    endif
#endif
 
    npl = hecmat%indexL(n)
    npu = hecmat%indexU(n)
    allocate(indexl(0:n), indexu(0:n), iteml(npl), itemu(npu))
    call hecmw_matrix_reorder_profile(n, perm, iperm, &
      hecmat%indexL, hecmat%indexU, hecmat%itemL, hecmat%itemU, &
      indexl, indexu, iteml, itemu)
    !write(*,*) 'DEBUG: reordering profile done', hecmw_Wtime()-t0
 
 
    allocate(d(4*n), al(4*npl), au(4*npu))
    call hecmw_matrix_reorder_values(n, 2, perm, iperm, &
      hecmat%indexL, hecmat%indexU, hecmat%itemL, hecmat%itemU, &
      hecmat%AL, hecmat%AU, hecmat%D, &
      indexl, indexu, iteml, itemu, al, au, d)
    !write(*,*) 'DEBUG: reordering values done', hecmw_Wtime()-t0
 
    call hecmw_matrix_reorder_renum_item(n, perm, indexl, iteml)
    call hecmw_matrix_reorder_renum_item(n, perm, indexu, itemu)
 
    allocate(alu(4*n))
    alu  = 0.d0
 
    do ii= 1, 4*n
      alu(ii) = d(ii)
    enddo
 
#ifdef _OPENACC
    !$acc kernels
    !$acc loop independent private(ALUtmp,PW)
#else
    !$omp parallel default(none),private(ii,ALUtmp,k,i,j,PW),shared(N,ALU,SIGMA_DIAG)
    !$omp do
#endif
    do ii= 1, n
      alutmp(1,1)= alu(4*ii-3) * sigma_diag
      alutmp(1,2)= alu(4*ii-2)
      alutmp(2,1)= alu(4*ii-1)
      alutmp(2,2)= alu(4*ii-0) * sigma_diag
      do k= 1, 2
        alutmp(k,k)= 1.d0/alutmp(k,k)
        do i= k+1, 2
          alutmp(i,k)= alutmp(i,k) * alutmp(k,k)
          do j= k+1, 2
            pw(j)= alutmp(i,j) - alutmp(i,k)*alutmp(k,j)
          enddo
          do j= k+1, 2
            alutmp(i,j)= pw(j)
          enddo
        enddo
      enddo
      alu(4*ii-3)= alutmp(1,1)
      alu(4*ii-2)= alutmp(1,2)
      alu(4*ii-1)= alutmp(2,1)
      alu(4*ii-0)= alutmp(2,2)
    enddo
#ifdef _OPENACC
    !$acc end kernels
#else
    !$omp end do
    !$omp end parallel
#endif
 
    isfirst = .true.
 
    initialized = .true.
    hecmat%Iarray(98) = 0 ! symbolic setup done
    hecmat%Iarray(97) = 0 ! numerical setup done
 
    !write(*,*) 'DEBUG: SSOR setup done', hecmw_Wtime()-t0
 
  end subroutine hecmw_precond_ssor_22_setup
 
  subroutine hecmw_precond_ssor_22_apply(ZP)
    use hecmw_tuning_fx
    implicit none
    real(kind=kreal), intent(inout) :: zp(:)
    integer(kind=kint) :: ic, i, iold, j, isl, iel, isu, ieu, k
    real(kind=kreal) :: sw(2), x(2)
 
    ! added for tuning >>>
    integer(kind=kint), parameter :: numofblockperthread = 100
    integer(kind=kint), save :: numofthread = 1, numofblock
    integer(kind=kint), save, allocatable :: ictoblockindex(:)
    integer(kind=kint), save, allocatable :: blockindextocolorindex(:)
    integer(kind=kint), save :: sectorcachesize0, sectorcachesize1
    integer(kind=kint) :: blockindex, elementcount, numofelement, ii
    real(kind=kreal) :: numofelementperblock
    integer(kind=kint) :: my_rank
 
#ifndef _OPENACC
    if (isfirst) then
      !$ numOfThread = omp_get_max_threads()
      numofblock = numofthread * numofblockperthread
      if (allocated(ictoblockindex)) deallocate(ictoblockindex)
      if (allocated(blockindextocolorindex)) deallocate(blockindextocolorindex)
      allocate (ictoblockindex(0:ncolor), &
        blockindextocolorindex(0:numofblock + ncolor))
      numofelement = n + indexl(n) + indexu(n)
      numofelementperblock = dble(numofelement) / numofblock
      blockindex = 0
      ictoblockindex = -1
      ictoblockindex(0) = 0
      blockindextocolorindex = -1
      blockindextocolorindex(0) = 0
      my_rank = hecmw_comm_get_rank()
      ! write(9000+my_rank,*) &
        !      '# numOfElementPerBlock =', numOfElementPerBlock
      ! write(9000+my_rank,*) &
        !      '# ic, blockIndex, colorIndex, elementCount'
      do ic = 1, ncolor
        elementcount = 0
        ii = 1
        do i = colorindex(ic-1)+1, colorindex(ic)
          elementcount = elementcount + 1
          elementcount = elementcount + (indexl(i) - indexl(i-1))
          elementcount = elementcount + (indexu(i) - indexu(i-1))
          if (elementcount > ii * numofelementperblock &
              .or. i == colorindex(ic)) then
            ii = ii + 1
            blockindex = blockindex + 1
            blockindextocolorindex(blockindex) = i
            ! write(9000+my_rank,*) ic, blockIndex, &
              !      blockIndexToColorIndex(blockIndex), elementCount
          endif
        enddo
        ictoblockindex(ic) = blockindex
      enddo
      numofblock = blockindex
 
      call hecmw_tuning_fx_calc_sector_cache( n, 2, &
        sectorcachesize0, sectorcachesize1 )
 
      isfirst = .false.
    endif
#endif
    ! <<< added for tuning
 
#ifndef _OPENACC
    !call start_collection("loopInPrecond33")
 
    !OCL CACHE_SECTOR_SIZE(sectorCacheSize0,sectorCacheSize1)
    !OCL CACHE_SUBSECTOR_ASSIGN(ZP)
 
    !$omp parallel default(none) &
      !$omp&shared(NColor,indexL,itemL,indexU,itemU,AL,AU,D,ALU,perm,&
      !$omp&       ZP,icToBlockIndex,blockIndexToColorIndex) &
      !$omp&private(SW,X,ic,i,iold,isL,ieL,isU,ieU,j,k,blockIndex)
#endif
 
    !C-- FORWARD
    do ic=1,ncolor
#ifdef _OPENACC
      !$acc kernels
      !$acc loop independent private(X,SW)
      do i = colorindex(ic-1)+1, colorindex(ic)
#else
      !$omp do schedule (static, 1)
      do blockindex = ictoblockindex(ic-1)+1, ictoblockindex(ic)
        do i = blockindextocolorindex(blockindex-1)+1, &
            blockindextocolorindex(blockindex)
#endif
          iold = perm(i)
          sw(1)= zp(2*iold-1)
          sw(2)= zp(2*iold-0)
          isl= indexl(i-1)+1
          iel= indexl(i)
          do j= isl, iel
            k= iteml(j)
            x(1)= zp(2*k-1)
            x(2)= zp(2*k-0)
            sw(1)= sw(1) - al(4*j-3)*x(1) - al(4*j-2)*x(2)
            sw(2)= sw(2) - al(4*j-1)*x(1) - al(4*j-0)*x(2)
          enddo ! j
 
          x = sw
          x(2)= x(2) - alu(4*i-1)*x(1)
          x(2)= alu(4*i  )*  x(2)
          x(1)= alu(4*i-3)*( x(1) - alu(4*i-2)*x(2))
          zp(2*iold-1)= x(1)
          zp(2*iold-0)= x(2)
#ifdef _OPENACC
      enddo
      !$acc end kernels
#else
        enddo ! i
      enddo ! blockIndex
      !$omp end do
#endif
    enddo ! ic
 
    !C-- BACKWARD
    do ic=ncolor, 1, -1
#ifdef _OPENACC
      !$acc kernels
      !$acc loop independent private(X,SW)
      do i = colorindex(ic-1)+1, colorindex(ic)
#else
      !$omp do schedule (static, 1)
      do blockindex = ictoblockindex(ic), ictoblockindex(ic-1)+1, -1
        do i = blockindextocolorindex(blockindex), &
            blockindextocolorindex(blockindex-1)+1, -1
#endif
          ! do blockIndex = icToBlockIndex(ic-1)+1, icToBlockIndex(ic)
          !   do i = blockIndexToColorIndex(blockIndex-1)+1, &
            !        blockIndexToColorIndex(blockIndex)
          !   do i = endPos(threadNum, ic), startPos(threadNum, ic), -1
          sw= 0.d0
          isu= indexu(i-1) + 1
          ieu= indexu(i)
          do j= ieu, isu, -1
            k= itemu(j)
            x(1)= zp(2*k-1)
            x(2)= zp(2*k-0)
            sw(1)= sw(1) + au(4*j-3)*x(1) + au(4*j-2)*x(2)
            sw(2)= sw(2) + au(4*j-1)*x(1) + au(4*j-0)*x(2)
          enddo ! j
 
          x = sw
          x(2)= x(2) - alu(4*i-1)*x(1)
 
 
          x(2)= alu(4*i  )*  x(2)
          x(1)= alu(4*i-3)*( x(1) - alu(4*i-2)*x(2) )
 
          iold = perm(i)
          zp(2*iold-1)=  zp(2*iold-1) - x(1)
          zp(2*iold  )=  zp(2*iold  ) - x(2)
#ifdef _OPENACC
      enddo
      !$acc end kernels
#else
        enddo ! i
      enddo ! blockIndex
      !$omp end do
#endif
    enddo ! ic
#ifndef _OPENACC
    !$omp end parallel
 
    !OCL END_CACHE_SUBSECTOR
    !OCL END_CACHE_SECTOR_SIZE
 
    !call stop_collection("loopInPrecond33")
#endif
 
  end subroutine hecmw_precond_ssor_22_apply
 
  subroutine hecmw_precond_ssor_22_clear(hecMAT)
    implicit none
    type(hecmwst_matrix), intent(inout) :: hecmat
    integer(kind=kint ) :: nthreads = 1
#ifndef _OPENACC
    !$ nthreads = omp_get_max_threads()
#endif
    if (associated(colorindex)) deallocate(colorindex)
    if (associated(perm)) deallocate(perm)
    if (associated(iperm)) deallocate(iperm)
    if (associated(alu)) deallocate(alu)
    if (nthreads >= 1) then
      if (associated(d)) deallocate(d)
      if (associated(al)) deallocate(al)
      if (associated(au)) deallocate(au)
      if (associated(indexl)) deallocate(indexl)
      if (associated(indexu)) deallocate(indexu)
      if (associated(iteml)) deallocate(iteml)
      if (associated(itemu)) deallocate(itemu)
    end if
    nullify(colorindex)
    nullify(perm)
    nullify(iperm)
    nullify(alu)
    nullify(d)
    nullify(al)
    nullify(au)
    nullify(indexl)
    nullify(indexu)
    nullify(iteml)
    nullify(itemu)
    initialized = .false.
  end subroutine hecmw_precond_ssor_22_clear
 
 
 
end module     hecmw_precond_ssor_22