hecmw_precond_DIAG_22.f90

Go to the documentation of this file.

!-------------------------------------------------------------------------------
! Copyright (c) 2019 FrontISTR Commons
! This software is released under the MIT License, see LICENSE.txt
!-------------------------------------------------------------------------------
 
!C
!C***
!C*** module hecmw_precond_DIAG_22
!C***
!C
module hecmw_precond_diag_22
  use  hecmw_util
 
  private
 
  public:: hecmw_precond_diag_22_setup
  public:: hecmw_precond_diag_22_apply
  public:: hecmw_precond_diag_22_clear
 
  integer(kind=kint) :: N
  real(kind=kreal), pointer :: alu(:) => null()
 
  logical, save :: INITIALIZED = .false.
 
contains
 
  subroutine hecmw_precond_diag_22_setup(hecMAT)
    use hecmw_matrix_misc
    implicit none
    type(hecmwst_matrix), intent(inout) :: hecmat
    integer(kind=kint ) :: np
    real   (kind=kreal) :: sigma_diag
    real(kind=kreal), pointer:: d(:)
 
    real   (kind=kreal):: alutmp(2,2), pw(2)
    integer(kind=kint ):: ii, i, j, k
 
    if (initialized) then
      if (hecmat%Iarray(98) == 0 .and. hecmat%Iarray(97) == 0) return
      call hecmw_precond_diag_22_clear()
    endif
 
    n = hecmat%N
    np = hecmat%NP
    d => hecmat%D
    sigma_diag = hecmw_mat_get_sigma_diag(hecmat)
 
    allocate(alu(4*np))
    alu = 0.d0
 
    do ii= 1, n
      alu(4*ii-3) = d(4*ii-3)
      alu(4*ii-2) = d(4*ii-2)
      alu(4*ii-1) = d(4*ii-1)
      alu(4*ii-0) = d(4*ii-0)
    enddo
 
    !$omp parallel default(none),private(ii,ALUtmp,k,i,j,PW),shared(N,ALU,SIGMA_DIAG)
    !$omp do
    do ii= 1, n
      alutmp(1,1)= alu(4*ii-3) * sigma_diag
      alutmp(1,2)= alu(4*ii-2)
      alutmp(2,1)= alu(4*ii-1)
      alutmp(2,2)= alu(4*ii-0) * sigma_diag
 
      do k= 1, 2
        alutmp(k,k)= 1.d0/alutmp(k,k)
        do i= k+1, 2
          alutmp(i,k)= alutmp(i,k) * alutmp(k,k)
          do j= k+1, 2
            pw(j)= alutmp(i,j) - alutmp(i,k)*alutmp(k,j)
          enddo
          do j= k+1, 2
            alutmp(i,j)= pw(j)
          enddo
        enddo
      enddo
      alu(4*ii-3)= alutmp(1,1)
      alu(4*ii-2)= alutmp(1,2)
      alu(4*ii-1)= alutmp(2,1)
      alu(4*ii-0)= alutmp(2,2)
    enddo
    !$omp end do
    !$omp end parallel
 
    initialized = .true.
    hecmat%Iarray(98) = 0 ! symbolic setup done
    hecmat%Iarray(97) = 0 ! numerical setup done
 
  end subroutine hecmw_precond_diag_22_setup
 
  subroutine hecmw_precond_diag_22_apply(WW)
    implicit none
    real(kind=kreal), intent(inout) :: ww(:)
    integer(kind=kint) :: i
    real(kind=kreal) :: x1, x2
 
    !C
    !C== Block SCALING
 
    !$omp parallel default(none),private(i,X1,X2),shared(N,WW,ALU)
    !$omp do
    do i= 1, n
      x1= ww(2*i-1)
      x2= ww(2*i-0)
      x2= x2 - alu(4*i-1)*x1
      x2= alu(4*i  )*  x2
      x1= alu(4*i-3)*( x1 - alu(4*i-2)*x2 )
      ww(2*i-1)= x1
      ww(2*i-0)= x2
    enddo
    !$omp end do
    !$omp end parallel
 
  end subroutine hecmw_precond_diag_22_apply
 
  subroutine hecmw_precond_diag_22_clear()
    implicit none
    if (associated(alu)) deallocate(alu)
    nullify(alu)
    initialized = .false.
  end subroutine hecmw_precond_diag_22_clear
 
end module     hecmw_precond_diag_22