fstr_solve_heat.f90

Go to the documentation of this file.

!-------------------------------------------------------------------------------
! Copyright (c) 2019 FrontISTR Commons
! This software is released under the MIT License, see LICENSE.txt
!-------------------------------------------------------------------------------
module m_fstr_solve_heat
contains
 
  subroutine fstr_solve_heat(hecMESH, hecMAT, fstrSOLID, fstrRESULT, fstrPARAM, fstrHEAT)
    use m_fstr
    use m_heat_init
    use m_heat_solve_tran
    use m_heat_io
    implicit none
    integer(kind=kint) :: ISTEP
    type(hecmwst_local_mesh)  :: hecMESH
    type(hecmwst_matrix)      :: hecMAT
    type(fstr_solid)          :: fstrSOLID
    type(hecmwst_result_data) :: fstrRESULT
    type(fstr_param)          :: fstrPARAM
    type(fstr_heat)           :: fstrHEAT
 
    integer(kind=kint) :: total_step, restart_step_num
    real(kind=kreal)   :: start_time, end_time
 
    call heat_init(hecmesh, fstrheat)
    call heat_init_log(hecmesh)
 
    if(fstrheat%restart_nout < 0) then
      call heat_input_restart(fstrheat, hecmesh, restart_step_num, total_step, start_time)
      end_time = fstrheat%STEP_EETIME(restart_step_num)
      if( (end_time - start_time) / end_time < 1.d-12 ) then
        restart_step_num = restart_step_num + 1
        start_time = 0.0d0
      endif
    else
      restart_step_num = 1
      total_step = 1
      start_time = 0.0d0
    endif
 
    do istep = restart_step_num, fstrheat%STEPtot
      fstrheat%is_steady = 0
      if(fstrheat%STEP_DLTIME(istep) <= 0.0d0) fstrheat%is_steady = 1
 
      if(hecmesh%my_rank == 0)then
        write(imsg,"(a,i8,a,i8)")"* Current step / Total step: ", istep, "/", fstrheat%STEPtot
        write(imsg,"(a,i8)")"* max iteration at each step: ", fstrparam%ITMAX(istep)
        if(fstrheat%is_steady == 1)then
          write(imsg,"(a)")"* Steady state analysis"
        else
          write(imsg,"(a)")"* Transient anslysis"
        endif
      endif
 
      call heat_solve_tran(hecmesh, hecmat, fstrsolid, fstrresult, fstrparam, fstrheat, istep, total_step, start_time)
 
      start_time = 0.0d0
    enddo
 
    call heat_finalize(fstrheat)
  end subroutine fstr_solve_heat
end module m_fstr_solve_heat