quad8n.f90

Go to the documentation of this file.

!-------------------------------------------------------------------------------
! Copyright (c) 2019 FrontISTR Commons
! This software is released under the MIT License, see LICENSE.txt
!-------------------------------------------------------------------------------
module shape_quad8n
  implicit none
 
  integer, parameter, private :: kreal = kind(0.0d0)
 
contains
  subroutine shapefunc_quad8n(lcoord,func)
    real(kind=kreal), intent(in) :: lcoord(2)
    real(kind=kreal) :: func(8)
    real(kind=kreal) :: ri,si,rp,sp,rm,sm
    ri=lcoord(1);  si=lcoord(2)
    rp=1.d0+lcoord(1)
    sp=1.d0+lcoord(2)
    rm=1.d0-lcoord(1)
    sm=1.d0-lcoord(2)
    func(1)=0.25d0*rm*sm*(-1.d0-ri-si)
    func(2)=0.25d0*rp*sm*(-1.d0+ri-si)
    func(3)=0.25d0*rp*sp*(-1.d0+ri+si)
    func(4)=0.25d0*rm*sp*(-1.d0-ri+si)
    func(5)=0.5d0*(1.d0-ri*ri)*(1.d0-si)
    func(6)=0.5d0*(1.d0-si*si)*(1.d0+ri)
    func(7)=0.5d0*(1.d0-ri*ri)*(1.d0+si)
    func(8)=0.5d0*(1.d0-si*si)*(1.d0-ri)
  end subroutine
 
  subroutine shapederiv_quad8n(lcoord,func)
    real(kind=kreal), intent(in) :: lcoord(2)
    real(kind=kreal) :: func(8,2)
    func(1,1)= .25d0*(1.d0-lcoord(2))*(2.d0*lcoord(1)+lcoord(2))
    func(2,1)= .25d0*(1.d0-lcoord(2))*(2.d0*lcoord(1)-lcoord(2))
    func(3,1)= .25d0*(1.d0+lcoord(2))*(2.d0*lcoord(1)+lcoord(2))
    func(4,1)= .25d0*(1.d0+lcoord(2))*(2.d0*lcoord(1)-lcoord(2))
    func(5,1)=-lcoord(1)*(1.d0-lcoord(2))
    func(6,1)= 0.5d0*(1.d0-lcoord(2)*lcoord(2))
    func(7,1)=-lcoord(1)*(1.d0+lcoord(2))
    func(8,1)=-0.5d0*(1.d0-lcoord(2)*lcoord(2))
 
 
    func(1,2)= .25d0*(1.d0-lcoord(1))*(lcoord(1)+2.d0*lcoord(2))
    func(2,2)=-.25d0*(1.d0+lcoord(1))*(lcoord(1)-2.d0*lcoord(2))
    func(3,2)= .25d0*(1.d0+lcoord(1))*(lcoord(1)+2.d0*lcoord(2))
    func(4,2)=-.25d0*(1.d0-lcoord(1))*(lcoord(1)-2.d0*lcoord(2))
    func(5,2)=-0.5d0*(1.d0-lcoord(1)*lcoord(1))
    func(6,2)=-lcoord(2)*(1.d0+lcoord(1))
    func(7,2)= 0.5d0*(1.d0-lcoord(1)*lcoord(1))
    func(8,2)=-lcoord(2)*(1.d0-lcoord(1))
  end subroutine
 
  subroutine shape2ndderiv_quad8n(lcoord,func)
    real(kind=kreal), intent(in) :: lcoord(2)
    real(kind=kreal) :: func(8,2,2)
    func(1,1,1) = 0.5d0*(1.d0-lcoord(2))
    func(2,1,1) = 0.5d0*(1.d0-lcoord(2))
    func(3,1,1) = 0.5d0*(1.d0+lcoord(2))
    func(4,1,1) = 0.5d0*(1.d0+lcoord(2))
    func(5,1,1) = lcoord(2)-1.d0
    func(6,1,1) = 0.d0
    func(7,1,1) =-lcoord(2)-1.d0
    func(8,1,1) = 0.d0
 
    func(1,1,2) = 0.25d0-0.5d0*(lcoord(1)+lcoord(2))
    func(2,1,2) =-0.25d0-0.5d0*(lcoord(1)-lcoord(2))
    func(3,1,2) = 0.25d0+0.5d0*(lcoord(1)+lcoord(2))
    func(4,1,2) =-0.25d0+0.5d0*(lcoord(1)-lcoord(2))
    func(5,1,2) = lcoord(1)
    func(6,1,2) =-lcoord(2)
    func(7,1,2) =-lcoord(1)
    func(8,1,2) = lcoord(2)
 
    func(1,2,1) = 0.25d0-0.5d0*(lcoord(1)+lcoord(2))
    func(2,2,1) =-0.25d0-0.5d0*(lcoord(1)-lcoord(2))
    func(3,2,1) = 0.25d0+0.5d0*(lcoord(1)+lcoord(2))
    func(4,2,1) =-0.25d0+0.5d0*(lcoord(1)-lcoord(2))
    func(5,2,1) = lcoord(1)
    func(6,2,1) =-lcoord(2)
    func(7,2,1) =-lcoord(1)
    func(8,2,1) = lcoord(2)
 
    func(1,2,2) = 0.5d0*(1.d0-lcoord(1))
    func(2,2,2) = 0.5d0*(1.d0+lcoord(1))
    func(3,2,2) = 0.5d0*(1.d0+lcoord(1))
    func(4,2,2) = 0.5d0*(1.d0-lcoord(1))
    func(5,2,2) = 0.d0
    func(6,2,2) =-lcoord(1)-1.d0
    func(7,2,2) = 0.d0
    func(8,2,2) = lcoord(1)-1.d0
  end subroutine
 
end module