hecmw_solver_las_44.F90

Go to the documentation of this file.

!-------------------------------------------------------------------------------
! Copyright (c) 2019 FrontISTR Commons
! This software is released under the MIT License, see LICENSE.txt
!-------------------------------------------------------------------------------
 
module hecmw_solver_las_44
  use hecmw_util
  implicit none
 
  private
 
  public :: hecmw_matvec_44
  public :: hecmw_matvec_44_set_async
  public :: hecmw_matvec_44_unset_async
  public :: hecmw_matresid_44
  public :: hecmw_rel_resid_l2_44
  public :: hecmw_tvec_44
  public :: hecmw_ttvec_44
  public :: hecmw_ttmattvec_44
  public :: hecmw_mat_diag_sr_44
 
  ! ! for communication hiding in matvec
  ! integer(kind=kint), save, allocatable :: index_o(:), item_o(:)
  ! real(kind=kreal), save, allocatable :: A_o(:)
  logical, save :: async_matvec_flg = .false.
 
contains
 
  !C
  !C***
  !C*** hecmw_matvec_44
  !C***
  !C
  subroutine hecmw_matvec_44 (hecMESH, hecMAT, X, Y, time_Ax, COMMtime)
    use hecmw_util
    use hecmw_matrix_misc
    implicit none
    type (hecmwst_local_mesh), intent(in) :: hecmesh
    type (hecmwst_matrix), intent(in), target :: hecmat
    real(kind=kreal), intent(in) :: x(:)
    real(kind=kreal), intent(out) :: y(:)
    real(kind=kreal), intent(inout) :: time_ax
    real(kind=kreal), intent(inout), optional :: commtime
 
    real(kind=kreal) :: tcomm
    real(kind=kreal), allocatable :: wk(:)
 
    tcomm = 0.d0
 
    if (hecmw_mat_get_flag_mpcmatvec(hecmat) /= 0) then
      allocate(wk(hecmat%NP * hecmat%NDOF))
      call hecmw_ttmattvec_44(hecmesh, hecmat, x, y, wk, time_ax, tcomm)
      deallocate(wk)
    else
      call hecmw_matvec_44_inner(hecmesh, hecmat, x, y, time_ax, tcomm)
    endif
 
    if (present(commtime)) commtime = commtime + tcomm
  end subroutine hecmw_matvec_44
 
  !C
  !C***
  !C*** hecmw_matvec_44_set_async
  !C***
  !C
  subroutine hecmw_matvec_44_set_async (hecMAT)
    use hecmw_util
    implicit none
    type (hecmwst_matrix), intent(in) :: hecmat
 
  end subroutine hecmw_matvec_44_set_async
 
  !C
  !C***
  !C*** hecmw_matvec_44_unset_async
  !C***
  !C
  subroutine hecmw_matvec_44_unset_async
    implicit none
 
  end subroutine hecmw_matvec_44_unset_async
 
  !C
  !C***
  !C*** hecmw_matvec_44_inner ( private subroutine )
  !C***
  !C
  subroutine hecmw_matvec_44_inner (hecMESH, hecMAT, X, Y, time_Ax, COMMtime)
    use hecmw_util
    use m_hecmw_comm_f
    use hecmw_matrix_misc
    use hecmw_jad_type
    use hecmw_tuning_fx
    !$ use omp_lib
 
    implicit none
    type (hecmwst_local_mesh), intent(in) :: hecmesh
    type (hecmwst_matrix), intent(in), target :: hecmat
    real(kind=kreal), intent(in) :: x(:)
    real(kind=kreal), intent(out) :: y(:)
    real(kind=kreal), intent(inout) :: time_ax
    real(kind=kreal), intent(inout), optional :: commtime
 
    real(kind=kreal) :: start_time, end_time, tcomm
    integer(kind=kint) :: i, j, js, je, in
    real(kind=kreal) :: yv1, yv2, yv3, yv4, x1, x2, x3, x4
 
    integer(kind=kint) :: n, np
    integer(kind=kint), pointer :: indexl(:), iteml(:), indexu(:), itemu(:), indexa(:), itema(:)
    real(kind=kreal), pointer :: al(:), au(:), d(:), a(:)
 
    ! added for turning >>>
    integer, parameter :: numofblockperthread = 100
    logical, save :: isfirst = .true.
    integer, save :: numofthread = 1
    integer, save, allocatable :: startpos(:), endpos(:)
    integer(kind=kint), save :: sectorcachesize0, sectorcachesize1
    integer(kind=kint) :: threadnum, blocknum, numofblock
    integer(kind=kint) :: numofelement, elementcount, blockindex
    real(kind=kreal) :: numofelementperblock
    ! <<< added for turning
 
    if (hecmw_jad_is_initialized().ne.0) then
      tcomm = 0.d0
      start_time = hecmw_wtime()
      call hecmw_jad_matvec(hecmesh, hecmat, x, y, tcomm)
      end_time = hecmw_wtime()
      time_ax = time_ax + end_time - start_time - tcomm
      if (present(commtime)) commtime = commtime + tcomm
    else
 
      n = hecmat%N
      np = hecmat%NP
      indexl => hecmat%indexL
      indexu => hecmat%indexU
      indexa => hecmat%indexA
      iteml => hecmat%itemL
      itemu => hecmat%itemU
      itema => hecmat%itemA
      al => hecmat%AL
      au => hecmat%AU
      d => hecmat%D
      a => hecmat%A
 
      ! added for turning >>>
#ifndef _OPENACC
      if (.not. isfirst) then
        numofblock = numofthread * numofblockperthread
        if (endpos(numofblock-1) .ne. n-1) then
          deallocate(startpos, endpos)
          isfirst = .true.
        endif
      endif
      if (isfirst) then
        !$ numOfThread = omp_get_max_threads()
        numofblock = numofthread * numofblockperthread
        allocate (startpos(0 : numofblock - 1), endpos(0 : numofblock - 1))
        numofelement = n + indexl(n) + indexu(n)
        numofelementperblock = dble(numofelement) / numofblock
        blocknum = 0
        elementcount = 0
        startpos(blocknum) = 1
        do i= 1, n
          elementcount = elementcount + 1
          elementcount = elementcount + (indexl(i) - indexl(i-1))
          elementcount = elementcount + (indexu(i) - indexu(i-1))
          if (elementcount > (blocknum + 1) * numofelementperblock) then
            endpos(blocknum) = i
            ! write(9000+hecMESH%my_rank,*) mod(blockNum, numOfThread), &
              !      startPos(blockNum), endPos(blockNum)
            blocknum = blocknum + 1
            startpos(blocknum) = i + 1
            if (blocknum == (numofblock - 1)) exit
          endif
        enddo
        endpos(blocknum) = n
        ! write(9000+hecMESH%my_rank,*) mod(blockNum, numOfThread), &
          !      startPos(blockNum), endPos(blockNum)
        ! for irregular data
        do i= blocknum+1, numofblock-1
          startpos(i) = n
          endpos(i) = n-1
          ! write(9000+hecMESH%my_rank,*) mod(i, numOfThread), &
            !      startPos(i), endPos(i)
        end do
 
        call hecmw_tuning_fx_calc_sector_cache(np, 4, &
          sectorcachesize0, sectorcachesize1)
 
        isfirst = .false.
      endif
#endif
      ! <<< added for turning
 
      start_time= hecmw_wtime()
 
      call hecmw_update_r (hecmesh, x, np, 4)
 
      ! endif
      end_time= hecmw_wtime()
      if (present(commtime)) commtime = commtime + end_time - start_time
 
      start_time = hecmw_wtime()
 
      !call fapp_start("loopInMatvec44", 1, 0)
      !call start_collection("loopInMatvec44")
 
      !OCL CACHE_SECTOR_SIZE(sectorCacheSize0,sectorCacheSize1)
      !OCL CACHE_SUBSECTOR_ASSIGN(X)
 
#ifdef _OPENACC
      !$acc kernels
      !$acc loop independent
      do i = 1, n
        x1= x(4*i-3)
        x2= x(4*i-2)
        x3= x(4*i-1)
        x4= x(4*i  )
        yv1= 0
        yv2= 0
        yv3= 0
        yv4= 0
        js= indexa(i) + 1
        je= indexa(i+1)
        do j= js, je
          in  = itema(j)
          x1= x(4*in-3)
          x2= x(4*in-2)
          x3= x(4*in-1)
          x4= x(4*in  )
          yv1= yv1 + a(16*j-15)*x1 + a(16*j-14)*x2 + a(16*j-13)*x3 + a(16*j-12)*x4
          yv2= yv2 + a(16*j-11)*x1 + a(16*j-10)*x2 + a(16*j- 9)*x3 + a(16*j- 8)*x4
          yv3= yv3 + a(16*j- 7)*x1 + a(16*j- 6)*x2 + a(16*j- 5)*x3 + a(16*j- 4)*x4
          yv4= yv4 + a(16*j- 3)*x1 + a(16*j- 2)*x2 + a(16*j- 1)*x3 + a(16*j   )*x4
        enddo
        y(4*i-3)= yv1
        y(4*i-2)= yv2
        y(4*i-1)= yv3
        y(4*i  )= yv4
      enddo
      !$acc end kernels
#else
      !$OMP PARALLEL DEFAULT(NONE) &
        !$OMP&PRIVATE(i,X1,X2,X3,X4,YV1,YV2,YV3,YV4,jS,jE,j,in,threadNum,blockNum,blockIndex) &
        !$OMP&SHARED(D,AL,AU,indexL,itemL,indexU,itemU,X,Y,startPos,endPos,numOfThread,N,async_matvec_flg)
      threadnum = 0
      !$ threadNum = omp_get_thread_num()
      do blocknum = 0 , numofblockperthread - 1
        blockindex = blocknum * numofthread  + threadnum
        do i = startpos(blockindex), endpos(blockindex)
          x1= x(4*i-3)
          x2= x(4*i-2)
          x3= x(4*i-1)
          x4= x(4*i  )
          yv1= d(16*i-15)*x1 + d(16*i-14)*x2 + d(16*i-13)*x3 + d(16*i-12)*x4
          yv2= d(16*i-11)*x1 + d(16*i-10)*x2 + d(16*i- 9)*x3 + d(16*i- 8)*x4
          yv3= d(16*i- 7)*x1 + d(16*i- 6)*x2 + d(16*i- 5)*x3 + d(16*i- 4)*x4
          yv4= d(16*i- 3)*x1 + d(16*i- 2)*x2 + d(16*i- 1)*x3 + d(16*i   )*x4
 
          js= indexl(i-1) + 1
          je= indexl(i  )
          do j= js, je
            in  = iteml(j)
            x1= x(4*in-3)
            x2= x(4*in-2)
            x3= x(4*in-1)
            x4= x(4*in  )
            yv1= yv1 + al(16*j-15)*x1 + al(16*j-14)*x2 + al(16*j-13)*x3 + al(16*j-12)*x4
            yv2= yv2 + al(16*j-11)*x1 + al(16*j-10)*x2 + al(16*j- 9)*x3 + al(16*j- 8)*x4
            yv3= yv3 + al(16*j- 7)*x1 + al(16*j- 6)*x2 + al(16*j- 5)*x3 + al(16*j- 4)*x4
            yv4= yv4 + al(16*j- 3)*x1 + al(16*j- 2)*x2 + al(16*j- 1)*x3 + al(16*j   )*x4
          enddo
          js= indexu(i-1) + 1
          je= indexu(i  )
          do j= js, je
            in  = itemu(j)
            ! if (async_matvec_flg .and. in > N) cycle
            x1= x(4*in-3)
            x2= x(4*in-2)
            x3= x(4*in-1)
            x4= x(4*in  )
            yv1= yv1 + au(16*j-15)*x1 + au(16*j-14)*x2 + au(16*j-13)*x3 + au(16*j-12)*x4
            yv2= yv2 + au(16*j-11)*x1 + au(16*j-10)*x2 + au(16*j- 9)*x3 + au(16*j- 8)*x4
            yv3= yv3 + au(16*j- 7)*x1 + au(16*j- 6)*x2 + au(16*j- 5)*x3 + au(16*j- 4)*x4
            yv4= yv4 + au(16*j- 3)*x1 + au(16*j- 2)*x2 + au(16*j- 1)*x3 + au(16*j   )*x4
          enddo
          y(4*i-3)= yv1
          y(4*i-2)= yv2
          y(4*i-1)= yv3
          y(4*i  )= yv4
        enddo
      enddo
      !$OMP END PARALLEL
#endif
 
      !OCL END_CACHE_SUBSECTOR
      !OCL END_CACHE_SECTOR_SIZE
 
      !call stop_collection("loopInMatvec44")
      !call fapp_stop("loopInMatvec44", 1, 0)
 
      end_time = hecmw_wtime()
      time_ax = time_ax + end_time - start_time
 
    endif
  end subroutine hecmw_matvec_44_inner
 
  !C
  !C***
  !C*** hecmw_matresid_44
  !C***
  !C
  subroutine hecmw_matresid_44 (hecMESH, hecMAT, X, B, R, time_Ax, COMMtime)
    use hecmw_util
    implicit none
    type (hecmwst_local_mesh), intent(in) :: hecmesh
    type (hecmwst_matrix), intent(in)     :: hecmat
    real(kind=kreal), intent(in) :: x(:), b(:)
    real(kind=kreal), intent(out) :: r(:)
    real(kind=kreal), intent(inout) :: time_ax
    real(kind=kreal), intent(inout), optional :: commtime
 
    integer(kind=kint) :: i
    real(kind=kreal) :: tcomm
 
    tcomm = 0.d0
    call hecmw_matvec_44 (hecmesh, hecmat, x, r, time_ax, tcomm)
    if (present(commtime)) commtime = commtime + tcomm
#ifdef _OPENACC
    !$acc kernels
    !$acc loop independent
#else
    !$omp parallel default(none),private(i),shared(hecMAT,R,B)
    !$omp do
#endif
    do i = 1, hecmat%N * 4
      r(i) = b(i) - r(i)
    enddo
#ifdef _OPENACC
    !$acc end kernels
#else
    !$omp end do
    !$omp end parallel
#endif
  end subroutine hecmw_matresid_44
 
  !C
  !C***
  !C*** hecmw_rel_resid_L2_44
  !C***
  !C
  function hecmw_rel_resid_l2_44 (hecMESH, hecMAT, time_Ax, COMMtime)
    use hecmw_util
    use hecmw_solver_misc
    implicit none
    real(kind=kreal) :: hecmw_rel_resid_l2_44
    type ( hecmwst_local_mesh ), intent(in) :: hecmesh
    type ( hecmwst_matrix     ), intent(in) :: hecmat
    real(kind=kreal), intent(inout) :: time_ax
    real(kind=kreal), intent(inout), optional :: commtime
 
    real(kind=kreal), allocatable :: r(:)
    real(kind=kreal) :: bnorm2, rnorm2
    real(kind=kreal) :: tcomm
 
    allocate(r(hecmat%NDOF*hecmat%NP))
 
    tcomm = 0.d0
    call hecmw_innerproduct_r(hecmesh, hecmat%NDOF, &
      hecmat%B, hecmat%B, bnorm2, tcomm)
    if (bnorm2 == 0.d0) then
      bnorm2 = 1.d0
    endif
    call hecmw_matresid_44(hecmesh, hecmat, hecmat%X, hecmat%B, r, time_ax, tcomm)
    call hecmw_innerproduct_r(hecmesh, hecmat%NDOF, r, r, rnorm2, tcomm)
    hecmw_rel_resid_l2_44 = sqrt(rnorm2 / bnorm2)
 
    if (present(commtime)) commtime = commtime + tcomm
 
    deallocate(r)
  end function hecmw_rel_resid_l2_44
 
  !C
  !C***
  !C*** hecmw_Tvec_44
  !C***
  !C
  subroutine hecmw_tvec_44 (hecMESH, X, Y, COMMtime)
    use hecmw_util
    use m_hecmw_comm_f
    implicit none
    type (hecmwst_local_mesh), intent(in) :: hecmesh
    real(kind=kreal), intent(in) :: x(:)
    real(kind=kreal), intent(out) :: y(:)
    real(kind=kreal), intent(inout) :: commtime
 
    real(kind=kreal) :: start_time, end_time
    integer(kind=kint) :: i, j, jj, k, kk
 
    start_time= hecmw_wtime()
    call hecmw_update_r (hecmesh, x, hecmesh%n_node, 4)
    end_time= hecmw_wtime()
    commtime = commtime + end_time - start_time
 
#ifdef _OPENACC
    !$acc kernels
    !$acc loop independent
#else
    !$omp parallel default(none),private(i,k,kk,j,jj),shared(hecMESH,X,Y)
    !$omp do
#endif
    do i= 1, hecmesh%nn_internal * hecmesh%n_dof
      y(i)= x(i)
    enddo
#ifndef _OPENACC
    !$omp end do
#endif
 
#ifdef _OPENACC
    !$acc loop independent
#else
    !$omp do
#endif
    outer: do i= 1, hecmesh%mpc%n_mpc
      do j= hecmesh%mpc%mpc_index(i-1) + 1, hecmesh%mpc%mpc_index(i)
        if (hecmesh%mpc%mpc_dof(j) > 4) cycle outer
      enddo
      k = hecmesh%mpc%mpc_index(i-1) + 1
      kk = 4 * (hecmesh%mpc%mpc_item(k) - 1) + hecmesh%mpc%mpc_dof(k)
      y(kk) = 0.d0
      do j= hecmesh%mpc%mpc_index(i-1) + 2, hecmesh%mpc%mpc_index(i)
        jj = 4 * (hecmesh%mpc%mpc_item(j) - 1) + hecmesh%mpc%mpc_dof(j)
        y(kk) = y(kk) - hecmesh%mpc%mpc_val(j) * x(jj)
      enddo
    enddo outer
#ifdef _OPENACC
    !$acc end kernels
#else
    !$omp end do
    !$omp end parallel
#endif
 
  end subroutine hecmw_tvec_44
 
  !C
  !C***
  !C*** hecmw_Ttvec_44
  !C***
  !C
  subroutine hecmw_ttvec_44 (hecMESH, X, Y, COMMtime)
    use hecmw_util
    use m_hecmw_comm_f
    implicit none
    type (hecmwst_local_mesh), intent(in) :: hecmesh
    real(kind=kreal), intent(in) :: x(:)
    real(kind=kreal), intent(out) :: y(:)
    real(kind=kreal), intent(inout) :: commtime
 
    real(kind=kreal) :: start_time, end_time
    integer(kind=kint) :: i, j, jj, k, kk
 
    start_time= hecmw_wtime()
    call hecmw_update_r (hecmesh, x, hecmesh%n_node, 4)
    end_time= hecmw_wtime()
    commtime = commtime + end_time - start_time
 
#ifdef _OPENACC
    !$acc kernels
    !$acc loop independent
#else
    !$omp parallel default(none),private(i,k,kk,j,jj),shared(hecMESH,X,Y)
    !$omp do
#endif
    do i= 1, hecmesh%nn_internal * hecmesh%n_dof
      y(i)= x(i)
    enddo
#ifndef _OPENACC
    !$omp end do
#endif
 
#ifdef _OPENACC
    !$acc loop independent
#else
    !$omp do
#endif
    outer: do i= 1, hecmesh%mpc%n_mpc
      do j= hecmesh%mpc%mpc_index(i-1) + 1, hecmesh%mpc%mpc_index(i)
        if (hecmesh%mpc%mpc_dof(j) > 4) cycle outer
      enddo
      k = hecmesh%mpc%mpc_index(i-1) + 1
      kk = 4 * (hecmesh%mpc%mpc_item(k) - 1) + hecmesh%mpc%mpc_dof(k)
      y(kk) = 0.d0
      do j= hecmesh%mpc%mpc_index(i-1) + 2, hecmesh%mpc%mpc_index(i)
        jj = 4 * (hecmesh%mpc%mpc_item(j) - 1) + hecmesh%mpc%mpc_dof(j)
#ifdef _OPENACC
        !$acc atomic update
#else
        !omp atomic
#endif
        y(jj) = y(jj) - hecmesh%mpc%mpc_val(j) * x(kk)
      enddo
    enddo outer
#ifdef _OPENACC
    !$acc end kernels
#else
    !$omp end do
    !$omp end parallel
#endif
 
  end subroutine hecmw_ttvec_44
 
  !C
  !C***
  !C*** hecmw_TtmatTvec_44
  !C***
  !C
  subroutine hecmw_ttmattvec_44 (hecMESH, hecMAT, X, Y, W, time_Ax, COMMtime)
    use hecmw_util
    implicit none
    type (hecmwst_local_mesh), intent(in) :: hecmesh
    type (hecmwst_matrix), intent(in)     :: hecmat
    real(kind=kreal), intent(in) :: x(:)
    real(kind=kreal), intent(out) :: y(:), w(:)
    real(kind=kreal), intent(inout) :: time_ax
    real(kind=kreal), intent(inout) :: commtime
 
    call hecmw_tvec_44(hecmesh, x, y, commtime)
    call hecmw_matvec_44_inner(hecmesh, hecmat, y, w, time_ax, commtime)
    call hecmw_ttvec_44(hecmesh, w, y, commtime)
 
  end subroutine hecmw_ttmattvec_44
 
 
  !C
  !C***
  !C*** hecmw_mat_diag_sr_44
  !C***
  !C
  subroutine hecmw_mat_diag_sr_44(hecMESH, hecMAT, COMMtime)
    use hecmw_util
    use m_hecmw_comm_f
    implicit none
    type (hecmwst_local_mesh), intent(in) :: hecmesh
    type (hecmwst_matrix), intent(inout), target :: hecmat
    real(kind=kreal), intent(inout), optional :: commtime
    real(kind=kreal), allocatable :: w(:,:)
    real(kind=kreal), pointer :: d(:)
    integer(kind=kint) :: ip
    real(kind=kreal) :: start_time, end_time
    allocate(w(4*hecmat%NP,4))
    d => hecmat%D
    do ip= 1, hecmat%N
      w(4*ip-3,1)= d(16*ip-15); w(4*ip-3,2)= d(16*ip-14); w(4*ip-3,3)= d(16*ip-13); w(4*ip-3,4)= d(16*ip-12)
      w(4*ip-2,1)= d(16*ip-11); w(4*ip-2,2)= d(16*ip-10); w(4*ip-2,3)= d(16*ip- 9); w(4*ip-2,4)= d(16*ip- 8)
      w(4*ip-1,1)= d(16*ip- 7); w(4*ip-1,2)= d(16*ip- 6); w(4*ip-1,3)= d(16*ip- 5); w(4*ip-1,4)= d(16*ip- 4)
      w(4*ip  ,1)= d(16*ip- 3); w(4*ip  ,2)= d(16*ip- 2); w(4*ip  ,3)= d(16*ip- 1); w(4*ip  ,4)= d(16*ip   )
    enddo
    start_time= hecmw_wtime()
    call hecmw_update_r (hecmesh, w(:,1), hecmat%NP, 4)
    call hecmw_update_r (hecmesh, w(:,2), hecmat%NP, 4)
    call hecmw_update_r (hecmesh, w(:,3), hecmat%NP, 4)
    call hecmw_update_r (hecmesh, w(:,4), hecmat%NP, 4)
    end_time= hecmw_wtime()
    if (present(commtime)) commtime = commtime + end_time - start_time
    do ip= hecmat%N+1, hecmat%NP
      d(16*ip-15)= w(4*ip-3,1); d(16*ip-14)= w(4*ip-3,2); d(16*ip-13)= w(4*ip-3,3); d(16*ip-12)= w(4*ip-3,4)
      d(16*ip-11)= w(4*ip-2,1); d(16*ip-10)= w(4*ip-2,2); d(16*ip- 9)= w(4*ip-2,3); d(16*ip- 8)= w(4*ip-2,4)
      d(16*ip- 7)= w(4*ip-1,1); d(16*ip- 6)= w(4*ip-1,2); d(16*ip- 5)= w(4*ip-1,3); d(16*ip- 4)= w(4*ip-1,4)
      d(16*ip- 3)= w(4*ip  ,1); d(16*ip- 2)= w(4*ip  ,2); d(16*ip- 1)= w(4*ip  ,3); d(16*ip   )= w(4*ip  ,4)
    enddo
    deallocate(w)
  end subroutine hecmw_mat_diag_sr_44
 
end module hecmw_solver_las_44